Tachymètre HO

[philippe017]

[ramasoft]

Ça fume Olivier

[patrice_b]

[ramasoft]

Aujourd'hui c'était une campagne d'essais avec différents matériels et il s'avère que les machines hautes sur pattes comme la BB9201 Jouef ne sont pas détectées.
La parade, c'est de coller un morceau de carton (genre carte de visite) recouvert d'aluminium ménager. On augmente ainsi la surface de la plaque du condensateur et ça fonctionne à près de 1cm du capteur. Il faut une surface assez large.

IMG_20260603_194214.jpg

IMG_20260603_194219.jpg

Deuxième enseignement, l'idée de la temporisation non bloquante permettant d’enchainer les mesures pose des problèmes sur les convois munis d'attelages bas ou de bogies bas avec des détections qui ne se font pas toujours sur les mêmes éléments et donnent des fausses mesures.
Alors j'ai corrigé ça avec une discrimination dans le code mais on est en train d'arriver à une usine à gaz juste pour dire qu'on va pouvoir faire des mesures les unes derrière les autres.
Donc j'ai abandonné et je suis revenu à la version 2.00 qui fonctionne avec des Delay tous bêtes... souvent le mieux est l'ennemi du bien

La version 2.00 qui sera définitive:
(on peut ajouter un message défilant en attente de mesure avec un scrolling de gauche à droite; il est juste désactivé en commentaire car ça ne me paraît pas bien utile.)

Code : Tout sélectionner

/* =========================================
 *    Tachymètre pour train à l'échelle HO
 *        V2.00 (c) Ramasoft 2026
 *    Mesure dans les deux sens de circulation
 * =========================================
 * Matériel :
 *   - Arduino Nano
 *   - Écran OLED 0,91" 128x32 (SSD1306) en I2C
 *   - 2 capteurs tactiles TTP223 (utilisés comme détecteurs de passage)
 *
 * Câblage :
 *   - Capteur 1 (S1) → D2  fil bleu
 *   - Capteur 2 (S2) → D3  fil vert
 *   - OLED SDA       → A4  fil blanc
 *   - OLED SCL       → A5  fil jaune
 *   - OLED VCC       → 5V 
 *   - OLED GND       → GND
 *
 * Note sur les TTP223 :
 *   Le TTP223 doit avoir ses plots A et B non shuntés = congiguration d'origine 
 *   pour sortir un état HAUT (HIGH) quand il détecte quelque chose et fonctionner en mode impulsion
 *
 * Distance entre capteurs : 30 cm (réelle = 30 / 87 m à l'échelle 1)
 *
 * Bibliothèques requises (à charger par le Gestionnaire de bibliothèques Arduino) :
 *   - Adafruit SSD1306
 *   - Adafruit GFX Library
 */
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// Configuration de l'écran OLED
#define SCREEN_WIDTH 128 
#define SCREEN_HEIGHT 32 // Modifier à 64 si votre écran est un 128x64
#define OLED_RESET     -1 
#define SCREEN_ADDRESS 0x3C 
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Configuration des capteurs
const int pinCapteur1 = 2; 
const int pinCapteur2 = 3; 

// Constantes pour le calcul (Échelle HO = 1/87)
const float distanceEntreCapteurs = 0.30; // Distance en mètres (30 cm)
const float echelle = 87.0;

// Variables de temps et de logique (volatile pour les interruptions)
volatile unsigned long tempsDepart = 0;
volatile unsigned long tempsFin = 0;
volatile boolean trainEnCours = false; // Indique qu'un train est entré dans la zone
volatile boolean mesureDispo = false;  // Indique que la mesure est prête
volatile int sensCirculation = 0;      // 1 = Sens 1->2, 2 = Sens 2->1

void setup() {
  //Configurer la LED interne (broche 13 sur le Nano) en sortie
  pinMode(LED_BUILTIN, OUTPUT);

  // Initialisation de l'écran
  // Si l'écran ne répond pas, on entre dans une boucle infinie de clignotement
  // de la LED rouge de l'Arduino
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    while(true) {
      digitalWrite(LED_BUILTIN, HIGH);
      delay(200);
      digitalWrite(LED_BUILTIN, LOW);
      delay(200);
    }
  }
  
  // Si l'écran fonctionne, le code continue normalement ici...
  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(5, 0);
  display.println("Tachymetre");
  display.setCursor(17, 18);
  display.println("HO V2.00");
  display.display();
  delay(10000);  // 10 secondes

  // Configuration des broches des capteurs (TTP223 sort un signal HIGH quand touché/activé)
  pinMode(pinCapteur1, INPUT);
  pinMode(pinCapteur2, INPUT);

  // Attachement des interruptions sur front montant (RISING)
  attachInterrupt(digitalPinToInterrupt(pinCapteur1), capteur1Declenche, RISING);
  attachInterrupt(digitalPinToInterrupt(pinCapteur2), capteur2Declenche, RISING);

  effaceEcran();
}

void loop() {
  if (mesureDispo) {
    float tempsMis = (tempsFin - tempsDepart) / 1000.0; 
    
    // Sécurité anti-rebond / fausse mesure
    if (tempsMis > 0.05) { 
      float vitesseReelle = distanceEntreCapteurs / tempsMis;
      float vitesseHO = vitesseReelle * echelle * 3.6;

      // display.stopscroll(); 
      display.clearDisplay();
      
      // Affichage du sens de circulation
      display.setTextSize(1);
      display.setCursor(0, 0);
      if (sensCirculation == 1) {
        display.print("Vitesse >>>> (1->2)");
      } else {
        display.print("Vitesse <<<< (2->1)");
      }
      
      // Affichage de la vitesse
      display.setTextSize(2);
      display.setCursor(0, 14); 
      display.print(vitesseHO, 1); // 1 chiffre après la virgule
      display.print(" km/h");
      display.display();
      
      delay(10000); // Reste affiché 10 secondes
    }
    
    // Réinitialisation pour le prochain train
    trainEnCours = false;
    mesureDispo = false;
    sensCirculation = 0;
    display.clearDisplay();
    effaceEcran();
  }
}

// Fonction d'interruption pour le capteur 1
void capteur1Declenche() {
  // CAS 1 : Le train arrive par le capteur 1 (Départ de la mesure)
  if (!trainEnCours) {
    tempsDepart = millis();
    sensCirculation = 1; // Sens 1 vers 2
    trainEnCours = true;
  }
  // CAS 2 : Le train arrivait du capteur 2 et vient de couper le capteur 1 (Fin de la mesure)
  else if (trainEnCours && sensCirculation == 2 && !mesureDispo) {
    tempsFin = millis();
    mesureDispo = true;
  }
}

// Fonction d'interruption pour le capteur 2
void capteur2Declenche() {
  // CAS 1 : Le train arrive par le capteur 2 (Départ de la mesure)
  if (!trainEnCours) {
    tempsDepart = millis();
    sensCirculation = 2; // Sens 2 vers 1
    trainEnCours = true;
  }
  // CAS 2 : Le train arrivait du capteur 1 et vient de couper le capteur 2 (Fin de la mesure)
  else if (trainEnCours && sensCirculation == 1 && !mesureDispo) {
    tempsFin = millis();
    mesureDispo = true;
  }
}

void effaceEcran() {
  display.clearDisplay();
  //display.setTextSize(2);
  //display.setCursor(0, 10);
  //display.print("En Attente");
  display.display();
  // Active le défilement horizontal vers la droite
  // Paramètres : (première page, dernière page) -> 0 et 0X0F couvre tout l'écran
  //display.startscrollright(0x00, 0x0F); 
}

Les STL seront sur Cults3D d'ici samedi.

Donc ces TTP223 sont une bonne trouvaille pour la détection et avec des plaques en alu sous les machine la détection est à 100% si bien qu'on pourrait envisager des applications plus sérieuses même dans le domaine de la sécurité.
Dans les idées que j'ai il y a bien sûr la commande d'un DFPlayer mais aussi la commande de servo pour un passage à niveau sophistiqué sur une double voie avec gestion de son et de lumière avec des temporisations. Je pense que le Nano doit avoir suffisamment de ressource pour cela.

Si vous avez d'autres idées, je suis preneur, sauf les trucs de logiciels car je suis hermétique à ça, mais des applications pour des animations dans le décor, des automatisations ou autre chose de fun.

[TrainDoly]

Je n'arrive pas à comprendre quelle distance tu vas prendre pour les deux points de mesure....

[herwat]

Excellente trouvaille, la plaque avec alu ! et

[C2Vues-BricoTrain]

Excellente trouvaille, la plaque avec alu ! et

C'est sûr, que quand tu "as lu" (alu), tu le sais !

[ramasoft]

Je n'arrive pas à comprendre quelle distance tu vas prendre pour les deux points de mesure....

Théoriquement 30 cm, mais une fois les capteurs posés je mesure précisément la distance entre le centre des capteurs et je recompile le code avec cette valeur.
Après entre 30cm et 31,5cm ... ça ne va pas changer énormément.

On peut mettre autre chose sachant que si on a des TGV qui roulent à fond une plus grande distance donnera plus de précision mais la mesure mettra plus de temps à arriver si le train roule lentement.
Et il faut aussi que ce soit en ligne droite.
Donc 30 cm, ça se trouve facilement et c'est un bon compromis.

[TrainDoly]

Donc la mesure ne pourra pas se faire sur tout les trains?

[ramasoft]

Mais si.
Quelle que soit la longueur du train, c'est quand la loco passe sur le 1er capteur que la mesure se déclenche.
Seule la toute première impulsion est prise en compte et elle seule.
Après, même si chaque essieu qui passe envoie une impulsion elle sera ignorée par le logiciel.

Ensuite la loco arrive sur le capteur 2 ce qui indique au logiciel que la mesure est terminée, le temps est relevé pour calculer la vitesse et l'afficher.

Le reste du convoi passe mais ça ne déclenche rien, car le logiciel est bloqué par une instruction delay(10000) de 10 secondes pendant lesquelles aucune impulsion n'est prise en compte.
Et au pire s'il y a un train très long qui met plus de 10 secondes pour parcourir les 30cm, il va déclencher simplement une deuxième mesure.
Donc si on n'a que des trains de 50 wagons, on pourra augmenter la période réfractaire à 15, 20 ou même 30 secondes.

La mesure est donc effectuée quelle que soit la longueur du convoi car c'est uniquement la 1ère impulsion sur chacun des capteurs qui est prise en compte. Que le train fasse 2m de long ou que ce soit une draisine de 10cm ça sera pareil: seul le premier bogie déclenche successivement les deux capteurs et tout le reste est ignoré.

Le risque d'erreur c'est si les deux capteurs n'ont pas la même sensibilité et que par exemple, le 1er est déclenché par le 1er bogie de la loco mais que le 2eme capteur n'est déclenché que par le 2eme bogie de la loco ou pire par un essieu du reste du convoi, alors la mesure sera fausse mais on s'en rendra compte tout de suite car la vitesse sera très minorée.
Mais dans tous les essais que j'ai fait avec tout un tas de matériel, ça ne s'est pas produit et toutes les mesures étaient cohérentes.

[TrainDoly]

Ha ouiiiii, j'ai compris!

[Tatak-Tatoum]

Merci pour le partage

[ramasoft]

Je suis en train de faire une vidéo qui sortira normalement samedi matin.
Les fichiers STL seront mis sur Cults3D et Thingiverse
Le code ainsi que la documentation seront à télécharger par un lien dans la description de la vidéo.

C'est un truc vite fait, vite posé et qui revient à 4€ maxi....

[TrainDoly]

Tu mettras les liens pour le matos?

[ramasoft]

Le matériel:
Écran OLED SSD1306 0,91 pouces
Arduino Nano
TTP223

Fixation des TTP sur la voie:

Cache TTP223.stl

Les boitiers: il y en a deux pour fixation sous le réseau et un qui intègre l'écran OLED et l'Arduino
L'Arduino se fixe avec des vis M1.2 de 1,2mm dans les trous prévus.

Capture d'écran 2026-06-04 190237.png

IMG_20260603_175342.jpg

Boitier Arduino Nano Oreilles 1.stl

Boitier Arduino Nano Oreilles 2.stl

Boitier Arduino Nano avec OLED Fond.stl

Boitier Arduino Nano avec OLED Couvercle.stl

Clip écran.stl

Le clip sert à fixer l'écran dans le boitier

IMG_20260601_145350.jpg

IMG_20260601_145417.jpg

IMG_20260602_210911.jpg

Le panneau pour intégration dans le décor avec deux petites rondelles pour cacher les trous dans le bois (socles panneau)
L'écran est coincé par une petit morceau de mousse et le fond tient clipsé = pas besoin de colle

Capture d'écran 2026-06-04 191019.png

IMG_20260601_144116.jpg

IMG_20260601_143946.jpg

IMG_20260601_143905.jpg

Panneau.stl

Socles Panneau.stl

Et les codes: V1 mesure dans un seul sens et V2 mesure dans les 2 sens avec documentation pour branchement et le sticker à coller pour repérer les broches pour la connexion.

Tachymètre_HO_Code_&_documentation.zip

Alimentation soit par la broche 5V avec du 5V bien régulé (4,5 < 5,5V) ou par VIN avec 7 à 12V (9V conseillés) ou par la prise USB.

Bonne réalisation

[Amigorl]

et pour ce partage.

[TrainDoly]

Ho la vache, je fonce construire ça!!!!!

Les gars, je vais mesurer la vitesse de tout mes trains!

[likiki]

[herwat]

et


Le problème avec les détecteurs, c'est que je ne pourrai pas les mettre dans l'eau pour mesurer la vitesse de ma péniche !

[Tatak-Tatoum]

Rigolo cette application des capteurs, merci pour ces partages toujours bienvenus !

[TrainDoly]

ça y est, j'ai commandé le matos!

[bunny94]

[philippe017]

[clbesson]

Encore un sujet très intéressant.
Merci pour ce partage Patrick.

[Lherve54]

Sujet bien documenté et vidéo qui complète le tout !